ExcelVBAでボリンジャーバンドを計算する

Sub TechnicalAnalysisCalc()
'テクニカル指標の計算

    '定数の定義
    Const FIRSTROW As Long = 2 'データ開始の行
    Const CloseP_C As Long = 5 '終値の列数
    Const BB_C As Long = 6   'ボリンジャーバンドを出力する最初の列


    '変数の定義
    Dim ChartData As Variant    'チャートデータを格納する配列
    Dim LastRow As Long         '最終行を格納する変数
    Dim BBTerm As Long 'ボリンジャーバンドの期間を格納する変数

    'アクティブワークシートの設定（シート名が、Sheet1のとき。シート名が違う場合は変更して下さい）
    Worksheets("Sheet1").Select
    
    'ボリンジャーバンドの過去の計算データクリア
    Range(Cells(FIRSTROW, BB_C), Cells(Rows.Count, BB_C + 6)).Clear

    '変数の初期化
    BBTerm = 20   'ボリンジャーバンドの期間（必要に応じて変更してください））
    LastRow = Cells(Cells(Rows.Count, 1).Row, 1).End(xlUp).Row '最終行の取得
    
    'チャートデータの取得(年月日から終値のデータを取得)
    ChartData = Range(Cells(FIRSTROW, 1), Cells(LastRow, CloseP_C))
    
    'ボリンジャーバンドのシートへの出力
    Range(Cells(FIRSTROW, BB_C), Cells(LastRow, BB_C + 6)) = BBcalc(ChartData, CloseP_C, BBTerm)

End Sub

Function BBcalc(ChartData, columnNum, Period)
'引数の概要
'ChartDataはチャートのデータ、CDNumはChartDataの移動平均線を計算する対象データの列、startRowは、columNumは計算結果を書込む列、Periodは移動平均線の期間
    
    '変数の定義
    Dim CDRowNum As Long 'チャートデータの行数
    Dim RowNum As Long  '計算している行
    Dim StDev As Double '標準偏差
    Dim Result As Variant   '結果を格納する配列
    
    'チャートデータ数の取得
    CDRowNum = UBound(ChartData, 1)

    '移動平均線を格納する配列の要素数を規定する
    ReDim Result(1 To CDRowNum, 6)
        
    '移動平均線の計算
    For RowNum = Period To CDRowNum
        Result(RowNum, 0) = AverageCalc(ChartData, columnNum, RowNum - Period + 1, RowNum) '平均値を計算し、結果を配列に格納する
        StDev = StDevPCalc(ChartData, columnNum, RowNum - Period + 1, RowNum)  '標準偏差の計算
        Result(RowNum, 1) = Result(RowNum, 0) + StDev
        Result(RowNum, 2) = Result(RowNum, 0) - StDev
        Result(RowNum, 3) = Result(RowNum, 0) + 2 * StDev
        Result(RowNum, 4) = Result(RowNum, 0) - 2 * StDev
        Result(RowNum, 5) = Result(RowNum, 0) + 3 * StDev
        Result(RowNum, 6) = Result(RowNum, 0) - 3 * StDev
    Next RowNum
    
    '結果を返す
    BBcalc = Result

End Function

Function AverageCalc(myArray, columnNum, startNum, endNum) As Double
'引数の概要
'myArrayは元データ、columnNum計算する要素の指定, starwNumは計算をスタートの配列の位置, endNumは計算が終わる配列の位置
    
    '変数の定義
    Dim i As Long
    Dim SumArr As Double
    
    '合計の初期化
    SumArr = 0

    '平均する数値の合計を計算
    For i = startNum To endNum
        SumArr = SumArr + myArray(i, columnNum)
    Next i
    
    '合計値を合計した数で割って平均値を算出し平均値を算出。平均値を返す。
    AverageCalc = SumArr / (endNum - startNum + 1)

End Function


Function StDevPCalc(myArray, columnNum, startNum, endNum) As Double
'myArrayは元データ、columnNum計算する要素の指定, starwNumは計算をスタートの配列の位置, endNumは計算が終わる配列の位置

'変数の定義
    Dim i As Long
    Dim DiffSum As Double
    Dim Ave As Double
    
    '合計の初期化
    DiffSum = 0
    
    '平均値の計算
    Ave = AverageCalc(myArray, columnNum, startNum, endNum)
    
    '平均との差の2乗の合計を計算
    For i = startNum To endNum
        DiffSum = DiffSum + (myArray(i, columnNum) - Ave) ^ 2
    Next i
    
    '標準偏差を計算して返す
    StDevPCalc = (DiffSum / (endNum - startNum + 1)) ^ 0.5

End Function