ExcelVBAでMACDを計算する

Sub TechnicalAnalysisCalc()
'テクニカル指標の計算

    '定数の定義
    Const FIRSTROW As Long = 2 'データ開始の行
    Const CloseP_C As Long = 5 '終値の列数
    Const MACD_C As Long = 6   'MACDを出力する最初の列


    '変数の定義
    Dim ChartData As Variant    'チャートデータを格納する配列
    Dim LastRow As Long         '最終行を格納する変数
    Dim MACDfastP, MACDslowP, MACDSignalP As Long 'MACDの期間を格納する変数

    'アクティブワークシートの設定（シート名が、Sheet1のとき。シート名が違う場合は変更して下さい）
    Worksheets("Sheet1").Select
    
    'MACDの過去の計算データクリア
    Range(Cells(FIRSTROW, MACD_C), Cells(Rows.Count, MACD_C + 2)).Clear

    '変数の初期化
    MACDfastP = 12 'MACD短期の指数移動平均の期間（必要に応じて変更してください）
    MACDslowP = 26 'MACD長期の指数移動平均の期間（必要に応じて変更してください）
    MACDSignalP = 9 'MACDシグナルの期間（必要に応じて変更してください）
    LastRow = Cells(Cells(Rows.Count, 1).Row, 1).End(xlUp).Row '最終行の取得
    
    'チャートデータの取得(年月日から終値のデータを取得)
    ChartData = Range(Cells(FIRSTROW, 1), Cells(LastRow, CloseP_C))
    
    'MACDの計算結果のシートへの出力
    Range(Cells(FIRSTROW, MACD_C), Cells(LastRow, MACD_C + 2)) = MACDcalc(ChartData, CloseP_C, MACDfastP, MACDslowP, MACDSignalP)

End Sub


Function MACDcalc(ChartData, columnNum, fastPeriod, slowPeriod, signalPeriod)
'MACDの計算

    '変数の定義
    Dim RowNum As Long
    Dim CDRowNum As Long
    Dim EmaCal As Variant '途中計算の結果の格納
    Dim Result As Variant '結果を格納する配列
    
    '最終行の計算
    CDRowNum = UBound(ChartData, 1)
    
    'EMAの計算結果を入れる配列の再定義
    ReDim EmaCal(1 To CDRowNum, 1)
    
    '結果を格納する配列の再定義（動的配列）
    ReDim Result(1 To CDRowNum, 2)

    '短期のEMA
    For RowNum = fastPeriod To CDRowNum
        EmaCal(RowNum, 0) = EMAcalc(ChartData, columnNum, RowNum - fastPeriod + 1, RowNum, EmaCal(RowNum - 1, 0))
    Next RowNum

    '長期のEMA
    For RowNum = slowPeriod To CDRowNum
        EmaCal(RowNum, 1) = EMAcalc(ChartData, columnNum, RowNum - slowPeriod + 1, RowNum, EmaCal(RowNum - 1, 1))
    Next RowNum

    'MACDの計算
    For RowNum = slowPeriod To CDRowNum
        Result(RowNum, 0) = EmaCal(RowNum, 0) - EmaCal(RowNum, 1)
    Next RowNum

    'MACDのEMA(シグナル)の計算
    For RowNum = slowPeriod + signalPeriod - 1 To CDRowNum
        Result(RowNum, 1) = EMAcalc(Result, 0, RowNum - signalPeriod + 1, RowNum, Result(RowNum - 1, 0))
    Next RowNum

    'MACDのヒストグラムの計算
    For RowNum = slowPeriod + signalPeriod - 1 To CDRowNum
        Result(RowNum, 2) = Result(RowNum, 0) - Result(RowNum, 1)
    Next RowNum
    
    '結果をセルに出力する
    MACDcalc = Result

End Function

Function EMAcalc(myArray, columnNum, startNum, endNum, PreEMA)

    '変数の定義
    Dim Period As Long
    Dim Alpha As Double
    
    'α（平滑化定数）の初期化
    Period = endNum - startNum + 1
    Alpha = 2 / (Period + 1)
    
    'EMAの計算
    If IsEmpty(PreEMA) Then
        EMAcalc = AverageCalc(myArray, columnNum, startNum, endNum) '先頭のみ単純平均
    Else
        EMAcalc = PreEMA + (myArray(endNum, columnNum) - PreEMA) * Alpha '2回目以降は指数平滑平均
    End If

End Function

Function AverageCalc(myArray, columnNum, startNum, endNum) As Double
'引数の概要
'myArrayは元データ、columnNum計算する要素の指定, starwNumは計算をスタートの配列の位置, endNumは計算が終わる配列の位置
    
    '変数の定義
    Dim i As Long
    Dim SumArr As Double
    
    '合計の初期化
    SumArr = 0

    '平均する数値の合計を計算
    For i = startNum To endNum
        SumArr = SumArr + myArray(i, columnNum)
    Next i
    
    '合計値を合計した数で割って平均値を算出し平均値を算出。平均値を返す。
    AverageCalc = SumArr / (endNum - startNum + 1)

End Function