ExcelVBAで一目均衡表を計算する

Sub TechnicalAnalysisCalc()
'テクニカル指標の計算

    '定数の定義
    Const FIRSTROW As Long = 2 'データ開始の行
    Const MaxP_C As Long = 3 '高値の列数
    Const MinP_C As Long = 4 '安値の列数
    Const CloseP_C As Long = 5 '終値の列数
    Const Ichimoku_C As Long = 6   '一目均衡表を出力する最初の列


    '変数の定義
    Dim ChartData As Variant    'チャートデータを格納する配列
    Dim LastRow As Long         '最終行を格納する変数
    Dim IchiTenP, IchiStdP, IchiSen2P As Long '一目均衡表の各種期間を格納する変数

    'アクティブワークシートの設定（シート名が、Sheet1のとき。シート名が違う場合は変更して下さい）
    Worksheets("Sheet1").Select
    
    '過去の計算データクリア
    Range(Cells(FIRSTROW, Ichimoku_C), Cells(Rows.Count, Ichimoku_C + 4)).Clear

    '変数の初期化
    IchiTenP = 9   '転換線の期間（必要に応じて変更してください）
    IchiStdP = 26 '基準線の期間（必要に応じて変更してください）
    IchiSen2P = 52   '先行スパン2の期間（必要に応じて変更してください）
    LastRow = Cells(Cells(Rows.Count, 1).Row, 1).End(xlUp).Row '最終行の取得
    
    'チャートデータの取得(年月日から終値のデータを取得)
    ChartData = Range(Cells(FIRSTROW, 1), Cells(LastRow, CloseP_C))
    
    '一目均衡表の計算結果の出力
    Range(Cells(FIRSTROW, Ichimoku_C), Cells(LastRow + IchiSen2P, Ichimoku_C + 4)) = IchimokuCalc(ChartData, MaxP_C, MinP_C, CloseP_C, IchiTenP, IchiStdP, IchiSen2P)
End Sub

Function IchimokuCalc(ChartData, MaxNum, MinNum, CloseNum, TenPeriod, StdPeriod, Sen2Period)
    
    '変数の定義
    Dim RowNum As Long
    Dim SenPeriod As Long
    Dim ChikoPeriod As Long
    Dim CDRowNum As Long
    Dim Result As Variant   '結果を格納する配列
    
    '最終行の取得
    CDRowNum = UBound(ChartData, 1)

    '初期化
    SenPeriod = StdPeriod
    ChikoPeriod = StdPeriod
    
    '変数の再定義（動的配列）
    ReDim Result(1 To CDRowNum + Sen2Period, 4)


    '基準線の計算
    For RowNum = StdPeriod To CDRowNum
        Result(RowNum, 0) = (MaxCalc(ChartData, MaxNum, RowNum - StdPeriod + 1, RowNum) + MinCalc(ChartData, MinNum, RowNum - StdPeriod + 1, RowNum)) / 2
    Next RowNum

    '転換線の計算
    For RowNum = TenPeriod To CDRowNum
        Result(RowNum, 1) = (MaxCalc(ChartData, MaxNum, RowNum - TenPeriod + 1, RowNum) + MinCalc(ChartData, MinNum, RowNum - TenPeriod + 1, RowNum)) / 2
    Next RowNum

    '先行スパン1の計算
    For RowNum = SenPeriod To CDRowNum
        Result(RowNum + SenPeriod, 2) = (Result(RowNum, 0) + Result(RowNum, 1)) / 2
    Next RowNum

    '先行スパン2の計算
    For RowNum = Sen2Period To CDRowNum
        Result(RowNum + SenPeriod, 3) = (MaxCalc(ChartData, MaxNum, RowNum - Sen2Period + 1, RowNum) + MinCalc(ChartData, MinNum, RowNum - Sen2Period + 1, RowNum)) / 2
    Next RowNum

    '遅行線の計算
    For RowNum = ChikoPeriod To CDRowNum
        Result(RowNum - ChikoPeriod + 1, 4) = ChartData(RowNum, CloseNum)
    Next RowNum
    
    '結果をセルに出力する
    IchimokuCalc = Result


End Function

Function MaxCalc(myArray, columnNum, startNum, endNum)
'最大値を算出する関数

    Dim MaxValue As Double
    Dim i As Long
    
    '最大値の初期値の入力
    MaxValue = myArray(startNum, columnNum)
    
    '最大値をMaxValueに代入
    For i = startNum To endNum
        If myArray(i, columnNum) > MaxValue Then
            MaxValue = myArray(i, columnNum)
        End If
    Next i
    
    MaxCalc = MaxValue
    
End Function

Function MinCalc(myArray, columnNum, startNum, endNum)
'最小値を算出する関数

    Dim MinValue As Double
    Dim i As Long
    
    '最小値の初期値の入力
    MinValue = myArray(startNum, columnNum)
    
    '最小値をMaxValueに代入
    For i = startNum To endNum
        If myArray(i, columnNum) < MinValue Then
            MinValue = myArray(i, columnNum)
        End If
    Next i
    
    MinCalc = MinValue
    
End Function