ExcelVBAでストキャスティクスを計算する

Sub TechnicalAnalysisCalc()
'テクニカル指標の計算

    '定数の定義
    Const FIRSTROW As Long = 2 'データ開始の行
    Const MaxP_C As Long = 3 '高値の列数
    Const MinP_C As Long = 4 '安値の列数
    Const CloseP_C As Long = 5 '終値の列数
    Const Stochastic_C As Long = 6   'ストキャスティックスのを出力する最初の列


    '変数の定義
    Dim chartData As Variant    'チャートデータを格納する配列
    Dim LastRow As Long         '最終行を格納する変数
    Dim StochKP, StochDP, StochSlowDP As Long 'ストキャスティックスの各種期間を格納する変数

    'アクティブワークシートの設定（シート名が、Sheet1のとき。シート名が違う場合は変更して下さい）
    Worksheets("Sheet1").Select
    
    '過去の計算データクリア
    Range(Cells(FIRSTROW, Stochastic_C), Cells(Rows.Count, Stochastic_C + 2)).Clear

    '変数の初期化
    StochKP = 14   '％Kの期間（必要に応じて変更してください）
    StochDP = 3 '％Dの期間（必要に応じて変更してください）
    StochSlowDP = 3   'Slow％Dの期間（必要に応じて変更してください）
    LastRow = Cells(Cells(Rows.Count, 1).Row, 1).End(xlUp).Row '最終行の取得
    
    'チャートデータの取得(年月日から終値のデータを取得)
    chartData = Range(Cells(FIRSTROW, 1), Cells(LastRow, CloseP_C))
    
    'ストキャスティックスの計算結果の出力
    Range(Cells(FIRSTROW, Stochastic_C), Cells(LastRow, Stochastic_C + 2)) = StochasticCalc(chartData, MaxP_C, MinP_C, CloseP_C, StochKP, StochDP, StochSlowDP)
End Sub

Function StochasticCalc(chartData, MaxNum, MinNum, CloseNum, kPeriod, dPeriod, slowdPeriod)

    '変数の定義
    Dim RowNum As Long
    Dim CDRowNum As Long
    Dim MinValue As Double
    Dim MaxValue As Double
    Dim Result As Variant   '結果を格納する配列
    
    '最終行の取得
    CDRowNum = UBound(chartData, 1)

    '変数の再定義（動的配列）
    ReDim Result(1 To CDRowNum, 3)
    

    'ストキャスティックスの計算
    For RowNum = kPeriod To CDRowNum
    
        MinValue = MinCalc(chartData, MinNum, RowNum - kPeriod + 1, RowNum)
        MaxValue = MaxCalc(chartData, MaxNum, RowNum - kPeriod + 1, RowNum)
        
        '%Kの計算
        Result(RowNum, 0) = 100 * (chartData(RowNum, CloseNum) - MinValue) / (MaxValue - MinValue)
        
        '%Dの計算
        If RowNum >= kPeriod + dPeriod - 1 Then
            Result(RowNum, 1) = AverageCalc(Result, 0, RowNum - dPeriod + 1, RowNum)
        End If
        
        'Slow%Dの計算
        If RowNum >= kPeriod + dPeriod + slowdPeriod - 2 Then
            Result(RowNum, 2) = AverageCalc(Result, 1, RowNum - slowdPeriod + 1, RowNum)
        End If

    Next RowNum
    
    '結果をセルに出力する
    StochasticCalc = Result

End Function


Function MaxCalc(myArray, columnNum, startNum, endNum)
'最大値を算出する関数

    Dim MaxValue As Double
    Dim i As Long
    
    '最大値の初期値の入力
    MaxValue = myArray(startNum, columnNum)
    
    '最大値をMaxValueに代入
    For i = startNum To endNum
        If myArray(i, columnNum) > MaxValue Then
            MaxValue = myArray(i, columnNum)
        End If
    Next i
    
    MaxCalc = MaxValue
    
End Function

Function MinCalc(myArray, columnNum, startNum, endNum)
'最小値を算出する関数

    Dim MinValue As Double
    Dim i As Long
    
    '最小値の初期値の入力
    MinValue = myArray(startNum, columnNum)
    
    '最小値をMaxValueに代入
    For i = startNum To endNum
        If myArray(i, columnNum) < MinValue Then
            MinValue = myArray(i, columnNum)
        End If
    Next i
    
    MinCalc = MinValue
    
End Function

Function AverageCalc(myArray, columnNum, startNum, endNum) As Double
'引数の概要
'myArrayは元データ、columnNum計算する要素の指定, starwNumは計算をスタートの配列の位置, endNumは計算が終わる配列の位置
    
    '変数の定義
    Dim i As Long
    Dim SumArr As Double
    
    '合計の初期化
    SumArr = 0

    '平均する数値の合計を計算
    For i = startNum To endNum
        SumArr = SumArr + myArray(i, columnNum)
    Next i
    
    '合計値を合計した数で割って平均値を算出し平均値を算出。平均値を返す。
    AverageCalc = SumArr / (endNum - startNum + 1)

End Function