ExcelVBAでSMAのゴールデンクロスとデッドクロスの判定をする

Sub TradeRule()

 '定数の定義
    Const FIRSTROW As Long = 2 'データ開始の行
    Const CloseP_C As Long = 5 '終値の列数
    Const SMA_S_C As Long = 6   '短期の単純移動平均線を出力する列
    Const SMA_M_C As Long = 7   '中期の単純移動平均線を出力する列
    Const SMA_L_C As Long = 8   '長期の単純移動平均線を出力する列


    '変数の定義
    Dim chartData As Variant    'チャートデータを格納する配列
    Dim LastRow As Long         '最終行を格納する変数

    'アクティブワークシートの設定（シート名が、Sheet1のとき。シート名が違う場合は変更して下さい）
    Worksheets("Sheet1").Select
    

    '変数の初期化
    LastRow = Cells(Cells(Rows.Count, 1).Row, 1).End(xlUp).Row '最終行の取得
    
     '過去の計算データクリア
    Range(Cells(FIRSTROW, SMA_L_C + 1), Cells(Rows.Count, SMA_L_C + 2)).Clear
    
    'チャートデータの取得(年月日から終値のデータを取得)
    chartData = Range(Cells(FIRSTROW, 1), Cells(LastRow, SMA_L_C))
    
    '短期と中期のゴールデンクロスを判定しその結果を出力（１ならゴールデンクロス）
    Range(Cells(FIRSTROW, SMA_L_C + 1), Cells(LastRow, SMA_L_C + 1)) = CrossOver(chartData, SMA_S_C, SMA_M_C)
    
    '短期と中期のデッドクロスを判定しその結果を出力（１ならデッドクロス）
    Range(Cells(FIRSTROW, SMA_L_C + 2), Cells(LastRow, SMA_L_C + 2)) = CrossOver(chartData, SMA_M_C, SMA_S_C)
    

End Sub

'2つの線がクロスオーバーしたかを判定する
Function CrossOver(chartData, Line1Num, Line2Num)

    '変数の定義
    Dim CDRowNum As Long
    Dim RowNum As Long
    Dim Result As Variant
    
    'チャートデータの行方向の要素数の取得
    CDRowNum = UBound(chartData, 1)
    
    '結果を代入する配列の要素数の決定
    ReDim Result(1 To CDRowNum, 1)
    
    For RowNum = 2 To CDRowNum
        If chartData(RowNum - 1, Line1Num) <> "" And chartData(RowNum - 1, Line2Num) <> "" Then
            If chartData(RowNum - 1, Line1Num) < chartData(RowNum - 1, Line2Num) And chartData(RowNum, Line1Num) > chartData(RowNum, Line2Num) Then
                Result(RowNum, 0) = 1
            End If
        End If
    Next RowNum
    
    CrossOver = Result
    
End Function